|
ealdrich -> RE: Wake On LAN (2/12/2008 9:00:50 AM)
|
We ran into this exact issue at one customer engagement... it seemed that these alerts were being generated all along, but were noit able to "go" anywhere until we poked 'em with the "Enable WOL" script... somehow that opened up the floodgates and they started spewing these alerts. To get around that issue, we used the following script to turnm it off, and *then* ran the WOL script... also an interesting side note: in some case3s when poking the BIOS on systems with a very *old* BIOS, when enabling WOL, we somehow disabled the "ECP" enhanced parallel port, breaking systems still using local parallel printers attached to PC. Lemmeno if you need that script as well if this is an issue.
Here's the Chassis Intrusion script:
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
'
' File: DellResetChassisIntrusion.vbs
'
' Purpose: To clear the chassis intrusion alert on a Dell OMCI client.
'
' Usage: cscript.exe DellResetChassisIntrusion.vbs <systemname>
'
' Input: systemname = Name of system to reset
'
' Requirements:
' - Dell Open Manage Client (see below for tested version)
' - Windows Script
' http://msdn.microsoft.com/library/default.asp?url=/downloads/list/webdev.asp
' - WMI version 1.5
'
' Notes:
' Tests performed using:
' Windows XP Professional SP2
' Windows Script v5.6
' Dell Open Manage Client version 6.1.1.259 or greater
' Precision 530MT ( success )
' Optiplex GX260 & GX280 ( success )
'
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Option Explicit
On Error Resume Next
'*** Declare variables
Dim strNameSpace
Dim strComputerName
Dim strClassName
Dim strKeyValue
Dim objInstance
Dim strPropName
Dim strPropValue
'*** Check that the right executable was used to run the script
'*** and that all parameters were passed
If (LCase(Right(WScript.FullName, 11)) = "wscript.exe" ) Or _
(Wscript.Arguments.Count < 1) Then
Call Usage()
WScript.Quit(-1)
End If
'*** Initialize variables
strNameSpace = "root/Dellomci"
strComputerName = WScript.Arguments(0)
strClassName = "Dell_SMBIOSSettings"
strKeyValue = "0"
strPropName = "ChassisIntrusionStatus"
'*** Retrieve the instance of Dell_SMBIOSSettings class
Set objInstance = GetObject("WinMgmts:{impersonationLevel=impersonate}//" & _
strComputerName & "/" & strNameSpace & ":" & strClassName & "=" & _
Chr(34) & strKeyValue & Chr(34))
strPropValue = objInstance.Properties_.Item(strPropName).Value
'*** Clear the value of ChassisIntrusionStatus only if it = 3
' A value of 3 = "Detected"
' Setting this value to 5 (Clear) will cause the ChassisIntrusionStatus
' property to really be reset to 4 (Not Detected).
If strPropValue = 3 then
'*** Set the new value for the property and save the instance
objInstance.Properties_.Item(strPropName).Value = 5
objInstance.Put_
'*** If any errors occurred, let the user know
If Err.Number <> 0 Then
WScript.Echo "Clearing the chassis intrusion alert failed."
End If
End If
Set objInstance = Nothing
WScript.Quit(Err.Number)
'*** Sub used to display the correct usage of the script
Sub Usage()
Dim strMessage
strMessage = "incorrect syntax. You should run: " & vbCRLF & _
"cscript.exe //nologo DellResetChassisIntrusion.vbs <systemname>"
WScript.Echo strMessage
End Sub
+++++++++++++
Hope this helps
|
|
|
|
